Equations defining a Jordan algebra

We consider Jordan algebras \(\mathcal{A}\) with unit \(U\) spanned by \(U,X,Y\). The bilinear form \(\bullet\) on \(\mathcal{A}\) is completely determined by \(X\bullet X\), \(X\bullet Y\) and \(Y\bullet Y\). These must all be linear combinations of \(U,X,Y\).

# We add some structure constants.
R.<lamb,mu> = PolynomialRing(QQ,2)

# We add constants to check the Jordan axiom.
S.<c1,c2,c3,d1,d2,d3> = PolynomialRing(R,6)

# We add the basis elements
T.<X,Y> = PolynomialRing(S,2)
U = 1

We here consider Jordan algebras where \(X\bullet X=X+\lambda Y\), \(X\bullet Y=\mu Y\) and \(Y\bullet Y=0\) for some \(\lambda,\mu\in\mathbb{C}\).

# We input the equalities determining * of some specific form.
XX = X+lamb*Y
XY = mu*Y
YY = 0

# We define the bilinear form * based on these equalities.
def mult(a,b):
    # input:  elements a,b of A, i.e. linear combinations of U,X,Y.
    # output: the product a*b
    f = a*b
    return XX*f.coefficient([2,0])+XY*f.coefficient([1,1])+YY*f.coefficient([0,2])+ X*f.coefficient([1,0])+Y*f.coefficient([0,1])+U*f.coefficient([0,0])

We now check the Jordan axiom.

# Next, we define general elements of A.
z = c1*U+c2*X+c3*Y
w = d1*U+d2*X+d3*Y

# We calculate (z*z)*(z*w)-z*((z*z)*w)
res = mult(mult(z,z),mult(z,w))-mult(z,mult(mult(z,z),w))

# res is a linear combination of U,X,Y.
# We consider the coefficients.
coeffs = res.coefficients()

# Each coefficient must be 0 for all c1,c2,c3,d1,d2,d3.
# The coefficients are polynomials in c1,c2,c3,d1,d2,d3.
# So all their coefficients must be 0. We factor these coefficients.
[cond.factor() for coeff in coeffs for cond in coeff.coefficients()]

[(-1) * mu * (mu - 1) * lamb, (-1) * mu * (mu - 1) * (2*mu - 1)]

We find that \(\mu(\mu-1)\lambda = \mu(\mu-1)(\mu-1/2) = 0\). So \(\mu = 0\), \(\mu = 1\) or \((\lambda,\mu)=(0,1/2)\).